sql server外鍵如果不合我們的心意，能不能進(jìn)行重命名呢？答案是肯定的。下文的例子就將為您示范sql server外鍵如何進(jìn)行重命名，供您參考。

本實例的數(shù)據(jù)庫原先是采用PowerDesigner設(shè)計的，那些外鍵約束的命名非常難看，并且也和后來在SSMS中額外添加的外鍵約束命名規(guī)則不一致，因此就像遍歷數(shù)據(jù)庫的所有外鍵約束，找到外鍵約束的相關(guān)對象，然后重新生成一致的命名。

采用的命名規(guī)則是：

FK_ForeignTable_PrimaryTable_On_ForeignColumn 

直白的翻譯就是，F(xiàn)oreignTable在ForeignColumn列上引用了PrimaryTable的主鍵。

Sql Server提供了很多動態(tài)管理視圖（Dynamic management views，DMV）和存儲過程，方便我們對數(shù)據(jù)庫進(jìn)行維護(hù)。這里我用到了以下兩個sys.foreign_key_columns（包含外鍵約束完整信息）和sys.objects（數(shù)據(jù)庫對象信息）這兩個DMV以及sp_rename執(zhí)行重命名的系統(tǒng)存儲過程。代碼如下：

declare fkcur cursor for   
 
select   
 
OBJECT_NAME(col.constraint_object_id) as FKConstraintName    
 
,fkTable.name as FKTable    
 
,fkCol.name as FKColumn    
 
,pkTable.name as PKTable    
 
,pkCol.name as PKColumn    
 
from sys.foreign_key_columns col    
 
-- 外鍵約束是建立在外鍵表上的，    
 
-- 因此foreign_key_columns表中的parent_object_id和parent_column_id分別表示外鍵表和外鍵列    
 
inner join sys.objects fkTable    
 
    on fkTable.object_id = col.parent_object_id    
 
inner join sys.columns fkCol    
 
    on fkCol.column_id = col.parent_column_id    
 
    and fkCol.object_id = fkTable.object_id    
 
-- foreign_key_columns表中的referenced_object_id和referenced_column_id分別指向    
 
-- 外鍵約束的主鍵表對象以及主鍵列    
 
inner join sys.objects pkTable    
 
    on pkTable.object_id = col.referenced_object_id    
 
inner join sys.columns pkCol    
 
    on pkCol.column_id = col.referenced_column_id    
 
    and pkCol.object_id = pkTable.object_id    
 
order by OBJECT_NAME(col.constraint_object_id)    
 
     
 
open fkcur    
 
declare @constraintName nvarchar(128)    
 
declare @fkTable nvarchar(64)    
 
declare @fkColumn nvarchar(64)    
 
declare @pkTable nvarchar(64)    
 
declare @pkColumn nvarchar(64)    
 
declare @newConstraintName nvarchar(128)    
 
     
 
fetch next from fkcur    
 
into @constraintName,@fkTable,@fkColumn,@pkTable,@pkColumn    
 
while @@FETCH_STATUS = 0    
 
begin   
 
    set @newConstraintName = 'FK_'+@fkTable+'_'+@pkTable+'_On_'+@fkColumn    
 
    exec sp_rename @constraintName,@newConstraintName,'Object'   
 
     
 
    fetch next from fkcur    
 
    into @constraintName,@fkTable,@fkColumn,@pkTable,@pkColumn    
 
end   
 
close fkcur    
 
deallocate fkcur   

【編輯推薦】

教您sql server外鍵的設(shè)置和刪除

sqlserver分頁存儲過程實例

sql server分頁的兩種方法比較

SQL SERVER分區(qū)視圖

帶您解讀SQL Server2008中的TIME數(shù)據(jù)類型