如果要讓sqlserver恢復(fù)到某個時間點(diǎn)的狀態(tài)，是否可行呢？答案是肯定的，下面就教您這種sqlserver恢復(fù)的方法，供您參考，希望在您學(xué)習(xí)sqlserver恢復(fù)的過程中能起到些許作用。

--創(chuàng)建測試數(shù)據(jù)庫   
CREATE DATABASE Db   
GO   
 
--對數(shù)據(jù)庫進(jìn)行備份   
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT   
GO   
 
--創(chuàng)建測試表   
CREATE TABLE Db.dbo.TB_test(ID int)   
 
--延時1秒鐘,再進(jìn)行后面的操作(這是由于SQL Server的時間精度最大為百分之三秒,不延時的話,可能會導(dǎo)致還原到時間點(diǎn)的操作失敗)   
WAITFOR DELAY '00:00:01'   
GO   
 
--假設(shè)我們現(xiàn)在誤操作刪除了 Db.dbo.TB_test 這個表   
DROP TABLE Db.dbo.TB_test   
 
--保存刪除表的時間   
SELECT dt=GETDATE() INTO #   
GO   
 
--在刪除操作后,發(fā)現(xiàn)不應(yīng)該刪除表 Db.dbo.TB_test   
 
--下面演示了如何恢復(fù)這個誤刪除的表 Db.dbo.TB_test   
 
--首先,備份事務(wù)日志(使用事務(wù)日志才能還原到指定的時間點(diǎn))   
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT   
GO   
 
--接下來,我們要先還原完全備份(還原日志必須在還原完全備份的基礎(chǔ)上進(jìn)行)   
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY   
GO   
 
--將事務(wù)日志還原到刪除操作前（這里的時間對應(yīng)上面的刪除時間，并比刪除時間略早   
DECLARE @dt datetime   
SELECT @dt=DATEADD(ms,-20,dt) FROM #  --獲取比表被刪除的時間略早的時間   
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt   
GO   
 
--查詢一下,看表是否恢復(fù)   
SELECT * FROM Db.dbo.TB_test   
 
/*--結(jié)果:   
ID             
-----------    
 
（所影響的行數(shù)為 0 行）   
--*/   
 
--測試成功   
GO   
 
--最后刪除我們做的測試環(huán)境   
DROP DATABASE Db   
DROP TABLE #   

【編輯推薦】

教您簡單學(xué)會sql server備份

sql server備份方法一覽

修改Sql Server系統(tǒng)表的方法

SQL Server系統(tǒng)表的作用

如何建立sql server存儲過程