鴻蒙內(nèi)核源碼分析(匯編匯總篇) | 鴻蒙所有的匯編代碼都在這里
51CTO和華為官方合作共建的鴻蒙技術(shù)社區(qū)
匯編其實(shí)很可愛
● 絕大部分IT從業(yè)人員終生不用觸碰到的匯編,它聽著像上古時(shí)代遙遠(yuǎn)的呼喚,總覺得遠(yuǎn)卻又能聽到聲,匯編再往下就真的是01110011了,匯編指令基本是一一對(duì)應(yīng)了機(jī)器指令.
● 所謂內(nèi)核是對(duì)硬件的驅(qū)動(dòng),對(duì)驅(qū)動(dòng)之后資源的良序管理,這里說(shuō)的資源是CPU(單核/多核),內(nèi)存,磁盤,i/o設(shè)備.層層封裝,步步遮蔽,到了應(yīng)用層,不知有漢,無(wú)論魏晉才好.好是好,但有句話,其實(shí)哪有什么歲月靜好,只是有人替你負(fù)重前行.難道你真的不想知道別人是怎么替你負(fù)重前行的?
● 越高級(jí)的語(yǔ)言是越接近人思維模式的,越低級(jí)的語(yǔ)言就是越貼近邏輯與非門的高低電平的起伏.匯編是貼著硬件飛行的,要研究?jī)?nèi)核就繞不過匯編,覺得神秘是來(lái)源于不了解,恐懼是來(lái)自于沒接近.
● 其實(shí)當(dāng)你深入分析內(nèi)核源碼之后就會(huì)發(fā)現(xiàn),匯編其實(shí)很可愛,很容易,比c/c++/java容易太多了,真的是很傻很單純.
鴻蒙內(nèi)核源碼分析系列篇至少已經(jīng)有五篇涉及到了匯編,請(qǐng)自行翻看,但還是遠(yuǎn)遠(yuǎn)不夠,要寫十五篇,徹底摸透,現(xiàn)在才剛剛開始,本篇先整理鴻蒙內(nèi)核所有匯編文件和大概說(shuō)明文件的作用,后續(xù)一塊一塊來(lái)剝,不把這些匯編剝個(gè)精光不罷休.
匯編目錄
鴻蒙所有匯編文件如下: 直接點(diǎn)擊可以查看注解源碼,有些站點(diǎn)會(huì)把鏈接去除,沒辦法,可直接去各大站點(diǎn)搜"鴻蒙內(nèi)核源碼分析",找到源碼注解.
● \arch\arm\arm\src
◆ startup 啟動(dòng)相關(guān)
◆ reset_vector_mp.S 多核CPU下啟動(dòng)代碼,大文件
◆ reset_vector_up.S 單核CPU下啟動(dòng)代碼,大文件
◆ armv7a
◆ cache.S 緩存相關(guān)的兩個(gè)函數(shù)
◆ los_dispatch.S 異常分發(fā)處理,大文件.
◆ los_hw_exc.S 硬件異常相關(guān),大文件.
◆ los_hw_runstop.S OsSRSaveRegister 和 OsSRRestoreRegister 匯編實(shí)現(xiàn)
◆ jmp.S 兩個(gè)簡(jiǎn)單的跳轉(zhuǎn)函數(shù)
◆ hw_user_get.S 拷貝用戶空間數(shù)據(jù)到內(nèi)核空間
◆ hw_user_put.S 拷貝內(nèi)核空間數(shù)據(jù)到用戶空間
hw_user_get.S
將用戶空間數(shù)據(jù)src 拷貝到內(nèi)核空間 dst
- // errno_t _arm_get_user(void *dst, const void *src, size_t dstTypeLen, size_t srcTypeLen)
- FUNCTION(_arm_get_user)
- stmdb sp!, {r0, r1, r2, r3, lr} @四個(gè)參數(shù)入棧,保存LR
- cmp r2, #0 @r2 和 0比較
- beq .Lget_user_return @相等 跳到Lget_user_return 直接返回
- cmp r2, r3 @r2 和 r3比較
- bne .Lget_user_err @不等,說(shuō)明函數(shù)要返回錯(cuò)誤
- cmp r2, #1 @r2 和 1比較
- bhi .Lget_user_half @if(dstTypeLen>1) 跳轉(zhuǎn)到Lget_user_half
- .Lget_user_byte: @按字節(jié)拷貝數(shù)據(jù)
- 0: ldrbt r3, [r1], #0 @r3=*r1
- 1: strb r3, [r0], #0 @*r0=r3
- b .Lget_user_return
- .Lget_user_half:
- cmp r2, #2 @r2 和 2比較
- bhi .Lget_user_word @if(dstTypeLen>2) Lget_user_word
- 2: ldrht r3, [r1], #0 @完成最后一個(gè)字節(jié)的拷貝
- 3: strh r3, [r0], #0 @完成最后一個(gè)字節(jié)的拷貝
- b .Lget_user_return
- .Lget_user_word:
- cmp r2, #4 @r2 和 4比較
- bhi .Lget_user_err @if(dstTypeLen>4) 跳轉(zhuǎn)到Lget_user_err
- 4: ldrt r3, [r1], #0
- 5: str r3, [r0], #0
- .Lget_user_return: @返回錨點(diǎn)
- ldmia sp!, {r0, r1, r2, r3, lr} @保存的內(nèi)容出棧,恢復(fù)各寄存器值
- mov r0, 0 @r0保存返回值為0
- bx lr @跳回調(diào)用函數(shù)繼續(xù)執(zhí)行,_arm_get_user到此結(jié)束!
- .Lget_user_err:
- ldmia sp!, {r0, r1, r2, r3, lr} @保存的內(nèi)容出棧,恢復(fù)各寄存器值
- mov r0, #-14 @r0保存返回值為-14
- bx lr @跳回調(diào)用函數(shù)繼續(xù)執(zhí)行,_arm_get_user到此結(jié)束!
- .pushsection __exc_table, "a"
- .long 0c, .Lget_user_err
- .long 1c, .Lget_user_err
- .long 2c, .Lget_user_err
- .long 3c, .Lget_user_err
- .long 4c, .Lget_user_err
- .long 5c, .Lget_user_err
- .popsection
hw_user_put.S
將內(nèi)核空間數(shù)據(jù)src 拷貝到用戶空間 dst
- // errno_t _arm_put_user(void *dst, const void *src, size_t dstTypeLen, size_t srcTypeLen)
- FUNCTION(_arm_put_user)
- stmdb sp!, {r0, r1, r2, r3, lr}
- cmp r2, #0
- beq .Lget_user_return
- cmp r2, r3
- bne .Lget_user_err
- cmp r2, #1
- bhi .Lget_user_half
- .Lget_user_byte:
- 0: ldrb r3, [r1], #0
- 1: strbt r3, [r0], #0
- b .Lget_user_return
- .Lget_user_half:
- cmp r2, #2
- bhi .Lget_user_word
- 2: ldrh r3, [r1], #0
- 3: strht r3, [r0], #0
- b .Lget_user_return
- .Lget_user_word:
- cmp r2, #4
- bhi .Lget_user_err
- 4: ldr r3, [r1], #0
- 5: strt r3, [r0], #0
- .Lget_user_return:
- ldmia sp!, {r0, r1, r2, r3, lr}
- mov r0, 0
- bx lr
- .Lget_user_err:
- ldmia sp!, {r0, r1, r2, r3, lr}
- mov r0, #-14
- bx lr
- .pushsection __exc_table, "a"
- .long 0c, .Lget_user_err
- .long 1c, .Lget_user_err
- .long 2c, .Lget_user_err
- .long 3c, .Lget_user_err
- .long 4c, .Lget_user_err
- .long 5c, .Lget_user_err
- .popsection
解讀
● 如果仔細(xì)對(duì)比一下發(fā)現(xiàn)這兩個(gè)函數(shù)的匯編代碼是一模一樣的,沒有區(qū)別.這就跟讓左右各一個(gè)美女陪你和左右各一個(gè)丑姑娘陪你的道理是一樣,都是1+1=2,算式加法的邏輯是一樣的,不會(huì)變.但給你的感覺能一樣嘛,美丑的含義是上層賦予的,到了這里美丑不重要,都變成了 r0,r1,r2,r3了, 跟咱東哥一樣臉盲分不清啦
● 用戶空間和內(nèi)核空間的數(shù)據(jù)為什么需要拷貝? 這是個(gè)經(jīng)典問題,看了網(wǎng)上的一些回答,沒毛病:
內(nèi)核不能信任任何用戶空間的指針。必須對(duì)用戶空間的指針指向的數(shù)據(jù)進(jìn)行驗(yàn)證。如果只做驗(yàn)證不做拷貝的話，那么在隨后的運(yùn)行中要隨時(shí)受到其它進(jìn)/線程可能修改用戶空間數(shù)據(jù)的威脅。所以必須做拷貝。
在內(nèi)存系列篇中已經(jīng)反復(fù)的說(shuō)過,每個(gè)用戶進(jìn)程都有自己獨(dú)立的用戶空間,但這個(gè)用戶空間是通過MMU映射出來(lái)的,是表面上繁花似錦,背后都共用著真正的物理內(nèi)存,所以在高頻率的任務(wù)切換過程中,原有的用戶空間地址內(nèi)容很容易被覆蓋掉.舉個(gè)例子說(shuō)明下:
◊ 用戶A客戶有個(gè)美女放在萬(wàn)聰酒店21號(hào)房說(shuō)要獻(xiàn)給內(nèi)核大佬,如果內(nèi)核不直接把美女接回家,而僅僅是做個(gè)記錄,寫著美女在萬(wàn)聰酒店21號(hào)房,內(nèi)核立馬跑去過還好不會(huì)錯(cuò),但如果被其他事給耽擱了呢?
◊ 耽擱的這回功夫,調(diào)度算法把萬(wàn)聰酒店21號(hào)房給了B客戶使用,當(dāng)然B客戶用之前酒店管理人員會(huì)把美女置換個(gè)地方(以至于A客戶再回到酒店時(shí),原來(lái)的東西該怎樣還咋樣). 等21號(hào)房空出來(lái)了,B肯定不知道原來(lái)的房間是A在用,而且里面還有個(gè)美女,更不可能曉得美女獻(xiàn)給內(nèi)核大佬了.因?yàn)锽的業(yè)務(wù)需要,很可能往21號(hào)房整了個(gè)東施進(jìn)來(lái).
◊ 此時(shí)如果內(nèi)核大佬事忙完了,想起A客戶獻(xiàn)美女的事了,是時(shí)候了.因?yàn)橹挥涗浟说刂?直接去萬(wàn)聰酒店21號(hào)房抓人,那抓出來(lái)可是東施呀.這可不把事給搞砸啦.
◊ 所以需要拷貝,直接把美女接回家找個(gè)地方關(guān)起來(lái)先.
reset_vector_mp.S 和 reset_vector_up.S
鴻蒙開機(jī)代碼根據(jù) CPU多核還是單核分成了兩個(gè)獨(dú)立文件處理. mp就是多處理器(multiprocessing)的意思: 多CPU核的操作系統(tǒng)3種處理模式(SMP+AMP+BMP) 鴻蒙實(shí)現(xiàn)的是 SMP 的方式
● 非對(duì)稱多處理(Asymmetric multiprocessing，AMP)每個(gè)CPU內(nèi)核 運(yùn)行一個(gè)獨(dú)立的操作系統(tǒng)或同一操作系統(tǒng)的獨(dú)立實(shí)例(instantiation)。
● 對(duì)稱多處理(Symmetric multiprocessing，SMP)一個(gè)操作系統(tǒng)的實(shí)例 可以同時(shí)管理所有CPU內(nèi)核，且應(yīng)用并不綁定某一個(gè)內(nèi)核。
● 混合多處理(Bound multiprocessing，BMP)一個(gè)操作系統(tǒng)的實(shí)例可以 同時(shí)管理所有CPU內(nèi)核，但每個(gè)應(yīng)用被鎖定于某個(gè)指定的核心。
up(unit processing )的意思,單個(gè)CPU,雖然沒mp的復(fù)雜,但文件也很大 500行匯編,一小節(jié)講不完,需要單獨(dú)的一篇專講 reset_vector
這里只列出up情況下的開機(jī)代碼
- reset_vector: @鴻蒙單核cpu 開機(jī)代碼
- /* do some early cpu setup: i/d cache disable, mmu disabled */
- mrc p15, 0, r0, c1, c0, 0
- bic r0, #(1<<12)
- bic r0, #(1<<2 | 1<<0)
- mcr p15, 0, r0, c1, c0, 0
- /* r11: delta of physical address and virtual address */
- adr r11, pa_va_offset
- ldr r0, [r11]
- sub r11, r11, r0
- /* if we need to relocate to proper location or not */
- adr r4, __exception_handlers /* r4: base of load address */
- ldr r5, =SYS_MEM_BASE /* r5: base of physical address */
- subs r12, r4, r5 /* r12: delta of load address and physical address */
- beq reloc_img_to_bottom_done /* if we load image at the bottom of physical address */
- /* we need to relocate image at the bottom of physical address */
- ldr r7, =__exception_handlers /* r7: base of linked address (or vm address) */
- ldr r6, =__bss_start /* r6: end of linked address (or vm address) */
- sub r6, r7 /* r6: delta of linked address (or vm address) */
- add r6, r4 /* r6: end of load address */
los_dispatch.S 和 los_hw_exc.S
異常模式處理入口和統(tǒng)一分發(fā)現(xiàn)實(shí),之前也有提到過,很復(fù)雜,1000多行,后續(xù)單獨(dú)細(xì)說(shuō)實(shí)現(xiàn)過程.
jmp.S
兩個(gè)簡(jiǎn)單的函數(shù)longjmp setjmp 的實(shí)現(xiàn),加注解部分請(qǐng)前往 鴻蒙內(nèi)核源碼注解分析 查看
- FUNCTION(longjmp)
- ldmfd r0,{r4-r12}
- add r0,#(4 * 9)
- ldr r13,[r0]
- add r0,#4
- ldr r14,[r0]
- cmp r1,#0
- moveq r1,#1
- mov r0,r1
- mov pc,lr
- FUNCTION(setjmp)
- stmea r0,{r4-r12}
- add r0,#(4 * 9)
- str r13,[r0]
- add r0,#4
- str r14,[r0]
- mov r0,#0
- mov pc,lr
los_hw_runstop.S
- .global OsSRSaveRegister
- .global OsSRRestoreRegister
兩個(gè)函數(shù)的匯編現(xiàn)實(shí),有點(diǎn)復(fù)雜,后續(xù)單獨(dú)說(shuō)明.
cache.S
這是緩存部分的兩個(gè)函數(shù)實(shí)現(xiàn),此處沒有加注解,試著看明白這兩個(gè)函數(shù)的實(shí)現(xiàn).加注解部分請(qǐng)前往 鴻蒙內(nèi)核源碼注解分析 查看
- .macro DCACHE_LINE_SIZE, reg, tmp
- mrc p15, 0, \tmp, c0, c0, 1
- lsr \tmp, \tmp, #16
- and \tmp, \tmp, #0xf
- mov \reg, #4
- mov \reg, \reg, lsl \tmp
- .endm
- FUNCTION(arm_inv_cache_range)
- push {r2, r3}
- DCACHE_LINE_SIZE r2, r3
- sub r3, r2, #1
- tst r0, r3
- bic r0, r0, r3
- mcrne p15, 0, r0, c7, c14, 1
- tst r1, r3
- bic r1, r1, r3
- mcrne p15, 0, r1, c7, c14, 1
- 1:
- mcr p15, 0, r0, c7, c6, 1
- add r0, r0, r2
- cmp r0, r1
- blo 1b
- dsb
- pop {r2, r3}
- mov pc, lr
- FUNCTION(arm_clean_cache_range)
- push {r2, r3}
- DCACHE_LINE_SIZE r2, r3
- sub r3, r2, #1
- bic r0, r0, r3
- 1:
- mcr p15, 0, r0, c7, c10, 1
- add r0, r0, r2
- cmp r0, r1
- blo 1b
- dsb
- pop {r2, r3}
- mov pc, lr
參與貢獻(xiàn)
● 訪問注解倉(cāng)庫(kù)地址
● Fork 本倉(cāng)庫(kù) >> 新建 Feat_xxx 分支 >> 提交代碼注解 >> 新建 Pull Request
● 新建 Issue
51CTO和華為官方合作共建的鴻蒙技術(shù)社區(qū)
